mirror of
https://git.code.sf.net/p/zint/code
synced 2026-05-01 11:45:29 +00:00
df64a0f237
template, props Dmitry Smirnov (ticket #147, props John Crisp); TODO: enable building with the GS1 Syntax Engine; this involved auditing copyrights which prompted the next item re "tif.c" and will prompt the next next item "pdf417.c" tif.c: replaced LZW compression with tree-based one due to "tif_lzw.h"'s original BSD-TAHOE license which has the equivalent of the "advertising clause", new implementation (which is much faster anyway) props Harald Kuhr and Bob Montgomery pdf417.c: TODO: Replace all code adapted from "pdf417.frm" as it was released under GPL v2.0 or later pdf417.h: replace unnecessary "pdf417.frm" references with ISO/IEC standard as 1st step re above, some expanded comments general: Codablock-F -> Codablock F (i.e. lose hyphen) cmake: frontend/frontend_qt: go back to only setting RPATH on macOS as not Debian compatible and it seems it's not a good idea on Linux anyway; TODO: check BSD + other Unixes CLI/GUI: make "--verbose" option official and document tools/gen_eci_sb_h.php/gen_eci_mb_h.php: add SPDX Unicode-3.0; update haible.de/bruno tarball info - "GB18030.TXT" no longer in "jdk-1.4.2/" so mention "libiconv-1.11/" version instead (same) general: add various SPDXs and normalize some Copyrights reedsol.c: malloced `logt`/`alog` tables int -> short (slight performance improvement) aztec.c: add copyrights, some code fiddling BWIPP: update to latest
64 lines
2.7 KiB
CMake
64 lines
2.7 KiB
CMake
# Copyright (C) 2008 by BogDan Vatra < bogdan@licentia.eu >
|
|
# Copyright (C) 2009-2026 Robin Stuart <rstuart114@gmail.com>
|
|
# SPDX-License-Identifier: GPL-3.0-or-later
|
|
# vim: set ts=4 sw=4 et :
|
|
|
|
cmake_minimum_required(VERSION 3.10)
|
|
project(zint-qt)
|
|
|
|
set(CMAKE_AUTORCC ON)
|
|
|
|
set(${PROJECT_NAME}_SRCS barcodeitem.cpp main.cpp mainwindow.cpp
|
|
cliwindow.cpp datawindow.cpp scalewindow.cpp sequencewindow.cpp exportwindow.cpp)
|
|
|
|
if(USE_QT6)
|
|
qt6_wrap_cpp(zint-qt_SRCS mainwindow.h cliwindow.h datawindow.h scalewindow.h sequencewindow.h exportwindow.h)
|
|
qt6_wrap_ui(zint-qt_SRCS mainWindow.ui extCLI.ui extData.ui extScale.ui extSequence.ui extExport.ui)
|
|
else()
|
|
qt5_wrap_cpp(zint-qt_SRCS mainwindow.h cliwindow.h datawindow.h scalewindow.h sequencewindow.h exportwindow.h)
|
|
qt5_wrap_ui(zint-qt_SRCS mainWindow.ui extCLI.ui extData.ui extScale.ui extSequence.ui extExport.ui)
|
|
endif()
|
|
|
|
if(APPLE)
|
|
# https://doc.qt.io/qt-5/appicon.html
|
|
set(MACOSX_BUNDLE_ICON_FILE zint-qt.icns)
|
|
set(APP_ICON_MACOSX "${CMAKE_CURRENT_SOURCE_DIR}/zint-qt.icns")
|
|
set_source_files_properties(${APP_ICON_MACOSX} PROPERTIES MACOSX_PACKAGE_LOCATION "Resources")
|
|
add_executable(${PROJECT_NAME} MACOSX_BUNDLE ${zint-qt_SRCS} resources.qrc ${APP_ICON_MACOSX})
|
|
set_target_properties(${PROJECT_NAME} PROPERTIES
|
|
MACOSX_BUNDLE TRUE
|
|
MACOSX_BUNDLE_BUNDLE_NAME "Zint Barcode Studio"
|
|
MACOSX_BUNDLE_BUNDLE_VERSION ${ZINT_VERSION}
|
|
MACOSX_BUNDLE_COPYRIGHT "Copyright © 2006-2025 Robin Stuart and others"
|
|
MACOSX_BUNDLE_GUI_IDENTIFIER "uk.org.zint.zint-qt"
|
|
MACOSX_BUNDLE_INFO_STRING "A free barcode generator"
|
|
MACOSX_BUNDLE_SHORT_VERSION_STRING ${ZINT_VERSION})
|
|
else()
|
|
add_executable(${PROJECT_NAME} ${zint-qt_SRCS} resources.qrc)
|
|
endif()
|
|
|
|
if(WIN32)
|
|
target_sources(${PROJECT_NAME} PRIVATE res/qtZint.rc)
|
|
endif()
|
|
|
|
target_include_directories(${PROJECT_NAME} PUBLIC "${CMAKE_CURRENT_SOURCE_DIR}/../backend" "${CMAKE_CURRENT_SOURCE_DIR}/../backend_qt")
|
|
|
|
if(ZINT_SHARED)
|
|
target_link_libraries(${PROJECT_NAME} zint)
|
|
else()
|
|
target_link_libraries(${PROJECT_NAME} zint-static)
|
|
endif()
|
|
target_link_libraries(${PROJECT_NAME} QZint
|
|
Qt${QT_VERSION_MAJOR}::UiTools Qt${QT_VERSION_MAJOR}::Gui Qt${QT_VERSION_MAJOR}::Svg
|
|
Qt${QT_VERSION_MAJOR}::Core)
|
|
|
|
if(APPLE AND NOT CMAKE_INSTALL_RPATH)
|
|
get_property(libdir GLOBAL PROPERTY ZINT_LIBDIR)
|
|
set_target_properties(${PROJECT_NAME} PROPERTIES INSTALL_RPATH "${CMAKE_INSTALL_RPATH};${libdir}")
|
|
endif()
|
|
|
|
install(TARGETS ${PROJECT_NAME} DESTINATION "${CMAKE_INSTALL_BINDIR}" RUNTIME)
|
|
if(UNIX)
|
|
install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/../docs/zint-qt.1" DESTINATION "${CMAKE_INSTALL_MANDIR}/man1" COMPONENT doc)
|
|
endif()
|