initial commit

bnowakow/old versions/GT7-B-Spec 0.985/Lib/AHK-ViGEm-Bus.ahk

@@ -0,0 +1,211 @@
+#include %A_LineFile%\..\CLR.ahk
+
+; Static class, holds ViGEm Client instance
+class ViGEmWrapper {
+	static asm := 0
+	static client := 0
+	
+	Init(){
+		if (this.client == 0){
+			this.asm := CLR_LoadLibrary(A_LineFile "\..\ViGEmWrapper.dll")
+		}
+	}
+	
+	CreateInstance(cls){
+		return this.asm.CreateInstance(cls)
+	}
+
+}
+
+; Base class for ViGEm "Targets" (Controller types - eg xb360 / ds4) to inherit from
+class ViGEmTarget {
+	target := 0
+	helperClass := ""
+	controllerClass := ""
+
+	__New(){
+		;~ this.asm := CLR_LoadLibrary(A_LineFile "\..\ViGEmWrapper.dll")
+		ViGEmWrapper.Init()
+		this.Instance := ViGEmWrapper.CreateInstance(this.helperClass)
+		
+		if (this.Instance.OkCheck() != "OK"){
+			msgbox ViGEmWrapper.dll failed to load!
+			ExitApp
+		}
+	}
+	
+	SendReport(){
+		this.Instance.SendReport()
+	}
+	
+	SubscribeFeedback(callback){
+		this.Instance.SubscribeFeedback(callback)
+	}
+}
+
+; DS4 (DualShock 4 for Playstation 4)
+class ViGEmDS4 extends ViGEmTarget {
+	helperClass := "ViGEmWrapper.Ds4"
+	__New(){
+		static buttons := {Square: 16, Cross: 32, Circle: 64, Triangle: 128, L1: 256, R1: 512, L2: 1024, R2: 2048
+			, Share: 4096, Options: 8192, LS: 16384, RS: 32768 }
+		static specialButtons := {Ps: 1, TouchPad: 2}
+		static axes := {LX: 2, LY: 3, RX: 4, RY: 5, LT: 0, RT: 1}
+		
+		this.Buttons := {}
+		for name, id in buttons {
+			this.Buttons[name] := new this._ButtonHelper(this, id)
+		}
+		for name, id in specialButtons {
+			this.Buttons[name] := new this._SpecialButtonHelper(this, id)
+		}
+		
+		this.Axes := {}
+		for name, id in axes {
+			this.Axes[name] := new this._AxisHelper(this, id)
+		}
+		
+		this.Dpad := new this._DpadHelper(this)
+		base.__New()
+	}
+	
+	class _ButtonHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetButtonState(this._Id, state)
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+	}
+	
+	class _SpecialButtonHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetSpecialButtonState(this._Id, state)
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+	}
+	
+	class _AxisHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetAxisState(this._Id, this.ConvertAxis(state))
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+		
+		ConvertAxis(state){
+			return round(state * 2.55)
+		}
+	}
+	
+	class _DpadHelper {
+		__New(parent){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			static dPadDirections := {Up: 0, UpRight: 1, Right: 2, DownRight: 3, Down: 4, DownLeft: 5, Left: 6, UpLeft: 7, None: 8}
+			this._Parent.Instance.SetDpadState(dPadDirections[state])
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+	}
+}
+
+; Xb360
+class ViGEmXb360 extends ViGEmTarget {
+	helperClass := "ViGEmWrapper.Xb360"
+	__New(){
+		static buttons := {A: 4096, B: 8192, X: 16384, Y: 32768, LB: 256, RB: 512, LS: 64, RS: 128, Back: 32, Start: 16, Xbox: 1024}
+		static axes := {LX: 2, LY: 3, RX: 4, RY: 5, LT: 0, RT: 1}
+		
+		this.Buttons := {}
+		for name, id in buttons {
+			this.Buttons[name] := new this._ButtonHelper(this, id)
+		}
+		
+		this.Axes := {}
+		for name, id in axes {
+			this.Axes[name] := new this._AxisHelper(this, id)
+		}
+		
+		this.Dpad := new this._DpadHelper(this)
+		
+		base.__New()
+	}
+	
+	class _ButtonHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetButtonState(this._Id, state)
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+	}
+	
+	class _AxisHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetAxisState(this._Id, this.ConvertAxis(state))
+			this._Parent.Instance.SendReport()
+		}
+		
+		ConvertAxis(state){
+			value := round((state * 655.36) - 32768)
+			if (value == 32768)
+				return 32767
+			return value
+		}
+	}
+	
+	class _DpadHelper {
+		_DpadStates := {1:0, 8:0, 2:0, 4:0} ; Up, Right, Down, Left
+		__New(parent){
+			this._Parent := parent
+		}
+		
+		SetState(state){
+			static dpadDirections := { None: {1:0, 8:0, 2:0, 4:0}
+				, Up: {1:1, 8:0, 2:0, 4:0}
+				, UpRight: {1:1, 8:1, 2:0, 4:0}
+				, Right: {1:0, 8:1, 2:0, 4:0}
+				, DownRight: {1:0, 8:1, 2:1, 4:0}
+				, Down: {1:0, 8:0, 2:1, 4:0}
+				, DownLeft: {1:0, 8:0, 2:1, 4:1}
+				, Left: {1:0, 8:0, 2:0, 4:1}
+				, UpLeft: {1:1, 8:0, 2:0, 4:1}}
+			newStates := dpadDirections[state]
+			for id, newState in newStates {
+				oldState := this._DpadStates[id]
+				if (oldState != newState){
+					this._DpadStates[id] := newState
+					this._Parent.Instance.SetButtonState(id, newState)
+				}
+				this._Parent.SendReport()
+			}
+		}
+	}
+}

bnowakow/old versions/GT7-B-Spec 0.985/Lib/CLR.ahk

@@ -0,0 +1,151 @@
+; ==========================================================
+;                  .NET Framework Interop
+;      https://autohotkey.com/boards/viewtopic.php?t=4633
+; ==========================================================
+;
+;   Author:     Lexikos
+;   Version:    1.2
+;   Requires:	AutoHotkey_L v1.0.96+
+;
+
+CLR_LoadLibrary(AssemblyName, AppDomain=0)
+{
+	if !AppDomain
+		AppDomain := CLR_GetDefaultDomain()
+	e := ComObjError(0)
+	Loop 1 {
+		if assembly := AppDomain.Load_2(AssemblyName)
+			break
+		static null := ComObject(13,0)
+		args := ComObjArray(0xC, 1),  args[0] := AssemblyName
+		typeofAssembly := AppDomain.GetType().Assembly.GetType()
+		if assembly := typeofAssembly.InvokeMember_3("LoadWithPartialName", 0x158, null, null, args)
+			break
+		if assembly := typeofAssembly.InvokeMember_3("LoadFrom", 0x158, null, null, args)
+			break
+	}
+	ComObjError(e)
+	return assembly
+}
+
+CLR_CreateObject(Assembly, TypeName, Args*)
+{
+	if !(argCount := Args.MaxIndex())
+		return Assembly.CreateInstance_2(TypeName, true)
+	
+	vargs := ComObjArray(0xC, argCount)
+	Loop % argCount
+		vargs[A_Index-1] := Args[A_Index]
+	
+	static Array_Empty := ComObjArray(0xC,0), null := ComObject(13,0)
+	
+	return Assembly.CreateInstance_3(TypeName, true, 0, null, vargs, null, Array_Empty)
+}
+
+CLR_CompileC#(Code, References="", AppDomain=0, FileName="", CompilerOptions="")
+{
+	return CLR_CompileAssembly(Code, References, "System", "Microsoft.CSharp.CSharpCodeProvider", AppDomain, FileName, CompilerOptions)
+}
+
+CLR_CompileVB(Code, References="", AppDomain=0, FileName="", CompilerOptions="")
+{
+	return CLR_CompileAssembly(Code, References, "System", "Microsoft.VisualBasic.VBCodeProvider", AppDomain, FileName, CompilerOptions)
+}
+
+CLR_StartDomain(ByRef AppDomain, BaseDirectory="")
+{
+	static null := ComObject(13,0)
+	args := ComObjArray(0xC, 5), args[0] := "", args[2] := BaseDirectory, args[4] := ComObject(0xB,false)
+	AppDomain := CLR_GetDefaultDomain().GetType().InvokeMember_3("CreateDomain", 0x158, null, null, args)
+	return A_LastError >= 0
+}
+
+CLR_StopDomain(ByRef AppDomain)
+{	; ICorRuntimeHost::UnloadDomain
+	DllCall("SetLastError", "uint", hr := DllCall(NumGet(NumGet(0+RtHst:=CLR_Start())+20*A_PtrSize), "ptr", RtHst, "ptr", ComObjValue(AppDomain))), AppDomain := ""
+	return hr >= 0
+}
+
+; NOTE: IT IS NOT NECESSARY TO CALL THIS FUNCTION unless you need to load a specific version.
+CLR_Start(Version="") ; returns ICorRuntimeHost*
+{
+	static RtHst := 0
+	; The simple method gives no control over versioning, and seems to load .NET v2 even when v4 is present:
+	; return RtHst ? RtHst : (RtHst:=COM_CreateObject("CLRMetaData.CorRuntimeHost","{CB2F6722-AB3A-11D2-9C40-00C04FA30A3E}"), DllCall(NumGet(NumGet(RtHst+0)+40),"uint",RtHst))
+	if RtHst
+		return RtHst
+	EnvGet SystemRoot, SystemRoot
+	if Version =
+		Loop % SystemRoot "\Microsoft.NET\Framework" (A_PtrSize=8?"64":"") "\*", 2
+			if (FileExist(A_LoopFileFullPath "\mscorlib.dll") && A_LoopFileName > Version)
+				Version := A_LoopFileName
+	if DllCall("mscoree\CorBindToRuntimeEx", "wstr", Version, "ptr", 0, "uint", 0
+	, "ptr", CLR_GUID(CLSID_CorRuntimeHost, "{CB2F6723-AB3A-11D2-9C40-00C04FA30A3E}")
+	, "ptr", CLR_GUID(IID_ICorRuntimeHost,  "{CB2F6722-AB3A-11D2-9C40-00C04FA30A3E}")
+	, "ptr*", RtHst) >= 0
+		DllCall(NumGet(NumGet(RtHst+0)+10*A_PtrSize), "ptr", RtHst) ; Start
+	return RtHst
+}
+
+;
+; INTERNAL FUNCTIONS
+;
+
+CLR_GetDefaultDomain()
+{
+	static defaultDomain := 0
+	if !defaultDomain
+	{	; ICorRuntimeHost::GetDefaultDomain
+		if DllCall(NumGet(NumGet(0+RtHst:=CLR_Start())+13*A_PtrSize), "ptr", RtHst, "ptr*", p:=0) >= 0
+			defaultDomain := ComObject(p), ObjRelease(p)
+	}
+	return defaultDomain
+}
+
+CLR_CompileAssembly(Code, References, ProviderAssembly, ProviderType, AppDomain=0, FileName="", CompilerOptions="")
+{
+	if !AppDomain
+		AppDomain := CLR_GetDefaultDomain()
+	
+	if !(asmProvider := CLR_LoadLibrary(ProviderAssembly, AppDomain))
+	|| !(codeProvider := asmProvider.CreateInstance(ProviderType))
+	|| !(codeCompiler := codeProvider.CreateCompiler())
+		return 0
+
+	if !(asmSystem := (ProviderAssembly="System") ? asmProvider : CLR_LoadLibrary("System", AppDomain))
+		return 0
+	
+	; Convert | delimited list of references into an array.
+	StringSplit, Refs, References, |, %A_Space%%A_Tab%
+	aRefs := ComObjArray(8, Refs0)
+	Loop % Refs0
+		aRefs[A_Index-1] := Refs%A_Index%
+	
+	; Set parameters for compiler.
+	prms := CLR_CreateObject(asmSystem, "System.CodeDom.Compiler.CompilerParameters", aRefs)
+	, prms.OutputAssembly          := FileName
+	, prms.GenerateInMemory        := FileName=""
+	, prms.GenerateExecutable      := SubStr(FileName,-3)=".exe"
+	, prms.CompilerOptions         := CompilerOptions
+	, prms.IncludeDebugInformation := true
+	
+	; Compile!
+	compilerRes := codeCompiler.CompileAssemblyFromSource(prms, Code)
+	
+	if error_count := (errors := compilerRes.Errors).Count
+	{
+		error_text := ""
+		Loop % error_count
+			error_text .= ((e := errors.Item[A_Index-1]).IsWarning ? "Warning " : "Error ") . e.ErrorNumber " on line " e.Line ": " e.ErrorText "`n`n"
+		MsgBox, 16, Compilation Failed, %error_text%
+		return 0
+	}
+	; Success. Return Assembly object or path.
+	return compilerRes[FileName="" ? "CompiledAssembly" : "PathToAssembly"]
+}
+
+CLR_GUID(ByRef GUID, sGUID)
+{
+	VarSetCapacity(GUID, 16, 0)
+	return DllCall("ole32\CLSIDFromString", "wstr", sGUID, "ptr", &GUID) >= 0 ? &GUID : ""
+}

bnowakow/old versions/GT7-B-Spec 0.985/PanAmerican1_V0.985.AHK

@@ -0,0 +1,640 @@
+#NoEnv
+#MaxHotkeysPerInterval 99000000
+#HotkeyInterval 99000000
+#KeyHistory 0
+#Include Lib\Gdip.ahk
+#include Lib\AHK-ViGEm-Bus.ahk
+
+ListLines Off
+Process, Priority, , A
+SetBatchLines, -1
+SetKeyDelay, -1, -1
+SetMouseDelay, -1
+SetDefaultMouseSpeed, 0
+SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
+
+SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
+DetectHiddenWindows, On
+#Persistent
+
+; --------- Constants 
+; Time at turn in seconds and Stablizing control
+t := 220000
+init_delay := 9700
+
+MenuDirect := "Right"
+Menu_loops := 6
+menu_s := 1
+box_size := 3
+color_check1 :=  0xBBE044
+color_check2 :=  0xBBE044
+color_2_delay := 1500
+
+color_tyre_overheat := 0xAF0019
+color_acquired_flag := 0x80C2E7
+color_purchase_button := 0xDCDCDC
+tyres_overheating := false
+tyreX := 150
+tyreY := 365
+purchaseX := 442
+purchaseY := 356
+acquiredX := 620
+acquiredY := 268
+
+; resolution parameters and pixel search locations
+ps_win_width  := 640
+ps_win_height := 360
+pix1x := 458
+pix1y := 114
+pix2x := 607
+pix2y := 319
+tolerance := 20
+bm_delay := 100
+box_size := 2
+
+ps_load_time1 := 14000
+ps_load_time2 := 7000 
+ps_load_time3 := 8400
+
+
+; Create a new controller controller
+controller := new ViGEmDS4()
+controller.SubscribeFeedback(Func("OnFeedback"))
+
+OnFeedback(largeMotor, smallMotor, lightbarColor){
+	;OutputDebug % "AHK| Feedback received - LargeMotor: " largeMotor ", SmallMotor:  " smallMotor ", LightBarColor: " lightbarColor
+}
+
+
+; ---------- Gui Setup -------------
+Gui, -MaximizeBox
+Gui, 2: -MaximizeBox
+Gui, 2: -MinimizeBox
+Gui, Color, c282a36, c6272a4
+Gui, Add, Button, x15 y10 w70 default, Start
+Gui, Add, Button, x15 y40 w70 default gVariableWindow, Variables
+Gui, Add, Button, x15 y70 w70 default gGetColo_p, Stuck Leaderboard
+Gui, Add, Button, x110 y70 w70 default gGetColo_g, Stuck Replay
+Gui, Add, Button, x110 y100 w70 default gBuyCars, Buy Cars
+Gui, Add, Button, x110 y10 w70 default gMenuTest, MenuTest
+Gui, Add, DropDownList, w50 Choose1 vMenuDirect, Right|Left
+Gui, Add, Edit, vMenu_loops w20 x165 y39, 6
+Gui, Font, ce8dfe3 s9 w550 Bold
+Gui, Add, Radio, Group x15 y130 altsubmit Checked gPSystem vSysCheck, PS5
+Gui, Add, Radio, x70 y130 altsubmit  gPSystem, PS4
+Gui, Add, Radio, x125 y130 altsubmit  gPSystem, PS4 Pro
+;Gui, Add, Radio, Group x15 y130 altsubmit Checked gMenuSel vMenuCheck, Pixel
+;Gui, Add, Radio, x70 y120 altsubmit  gMenuSel, Timing
+Gui, Add, Button, x70 y150 w70 default gReset, Reset
+Gui, Font, ce8dfe3 s9 w550 Bold
+
+;--------- Gui 2 Setup --------------
+Gui, 2: Color, c535770, c6272a4
+Gui, 2: Font, c11f s9 Bold
+Gui, 2: Add, Text,, Turn Length (time miliseconds)
+Gui, 2: Add, Edit,  w70 vA, %t%
+Gui, 2: Add, Text, x100 y90, Color 2 Delay
+Gui, 2: Add, Edit, x100 y110 w40 vD, %color_2_delay%
+
+Gui, 2: Add, Button, x20  y170 gSaveVars, Save 
+Gui, 2: Add, Button, x100 y170 gVarDef, Defaults
+Gui, Show,w220 h185,  GT7 Pan American AFK
+return
+
+BuyCars:
+    loop {
+            carIsAcquired := false
+            loop {
+                c1 := BitGrab(620, 268, box_size)
+                for i, c in c1
+                {
+                    d1 := Distance(c, 0x7B7B7B)
+                    if (d1 < tolerance ){
+                        carIsAcquired := true
+                        break
+                    }
+                }
+
+                if (carIsAcquired)
+                    break
+
+                controller.Dpad.SetState("Right")
+                Sleep, 200
+                controller.Dpad.SetState("None")
+                Sleep, 200
+            }
+
+        gosub, PressX
+        Sleep, 500
+        loop {
+            inPurchaseMenu := false
+            c1 := BitGrab(purchaseX, purchaseY, box_size)
+            for i, c in c1
+            {
+                d1 := Distance(c, color_purchase_button)
+                if (d1 < tolerance ){
+                    inPurchaseMenu := true
+                    break
+                }
+            }
+            if (inPurchaseMenu)
+                break
+            gosub, PressX
+            Sleep, 500
+        }
+        loop, 4 {
+            controller.Dpad.SetState("Right")
+            Sleep, 200
+            controller.Dpad.SetState("None")
+            Sleep, 200
+        }
+        loop, 2 {
+            gosub, PressX
+            Sleep, 500
+        }
+        carIsAcquired := false
+        Sleep, 1500
+        loop {
+            c1 := BitGrab(acquiredX, acquiredY, box_size)
+                for i, c in c1
+                {
+                    d1 := Distance(c, color_acquired_flag)
+                    if (d1 < tolerance ){
+                        carIsAcquired := true
+                        break
+                    }
+                }
+
+                if (carIsAcquired)
+                    break
+
+                gosub, PressX
+        }
+        Sleep, 1000
+    }
+return
+
+VariableWindow:
+    Gui, 2: Show, w220 h205, Variables
+    return
+
+SaveVars:
+    Gui, 2:Submit
+    GuiControlGet, t, 2:, A
+    GuiControlGet, color_2_delay, 2:, D
+    return
+
+VarDef:
+    GuiControl, 2:, A, %t%
+    GuiControl, 2:, D, %color_2_delay%
+    return
+
+ButtonStart:
+    Gui, Submit, NoHide
+    id := ""
+    SetKeyDelay, 10
+    Process, priority, , High
+    gosub, GrabRemotePlay
+    if  (id = "")
+        return
+    gosub, PauseLoop
+    CoordMode, Pixel, Screen
+    CoordMode, ToolTip, Screen
+    sleep 1000
+    gosub, AFKLoop
+; ---------- Gui Setup End-------------
+
+	
+AFKLoop:
+    loop{
+		 gosub, PressX
+        DllCall("Sleep", "UInt", init_delay)
+        gosub, Race
+        if (tyres_overheating) { 
+            break 
+        }
+        gosub, Menu
+    }
+    return
+
+PressX:
+; Just for menuing, does not hold X down
+    controller.Buttons.Cross.SetState(true)
+	DllCall("Sleep", "UInt", 200)
+    controller.Buttons.Cross.SetState(false)
+    return
+
+CheckTyresOverheating:
+    tc := BitGrab(tyreX, tyreY, box_size)
+    for i, c in tc
+    {
+        td := Distance(c, color_tyre_overheat)
+        if (td < tolerance ){
+            tyres_overheating := true
+            break
+        }
+    }
+    return
+
+RetryRace:
+    Gosub, PauseLoop
+    Sleep 500
+    tyres_overheating := false
+    controller.Buttons.Options.SetState(true)
+    Sleep 500
+	controller.Buttons.Options.SetState(false)
+    Sleep, 500
+    WinActivate, ahk_id %id%
+    Sleep, 500
+    controller.Dpad.SetState("Right") 
+    Sleep, 200
+    controller.Dpad.SetState("None") 
+    Goto, AFKLoop
+    return
+
+Race:
+; Hold Acceleration and manage turning
+    
+	controller.Buttons.Cross.SetState(true)
+	controller.Buttons.RS.SetState(true)
+	DllCall("Sleep", "UInt", 8200)
+    SetTimer, CheckTyresOverheating, Off
+    SetTimer, CheckTyresOverheating, 1000
+	controller.Axes.LX.SetState(65)
+
+    t0 := A_TickCount
+	tf := t0+t
+	loop 	{
+		 DllCall("Sleep", "UInt", 500)
+	} until tyres_overheating || A_TickCount > tf
+
+    loop {
+        if (tyres_overheating) {
+            Goto, RetryRace
+            return
+        }
+        SetTimer, CheckTyresOverheating, Off
+        break_point := false
+        c1 := BitGrab(pix1x, pix1y, box_size)
+        for i, c in c1
+        {
+            d1 := Distance(c, color_check1)
+            if (d1 < tolerance ){
+                break_point := true
+                break
+            }
+        }
+        Sleep, 500
+        if (break_point)
+            break
+        controller.Dpad.SetState("Right") 
+        Sleep, 140
+        controller.Dpad.SetState("None") 
+        Sleep, 200
+    }
+    controller.Buttons.Cross.SetState(false) 
+	controller.Dpad.SetState("None") 
+    controller.Axes.LX.SetState(50)
+    controller.Buttons.RS.SetState(false)
+    return
+    
+Menu:
+    gosub, Menu_pixel
+return
+
+Menu_pixel:
+     loop {
+        break_point := false
+         c2 := BitGrab(pix2x, pix2y, box_size)
+        for i, c in c2
+        {
+            d2 := Distance(c, color_check2)
+            if (d2 < tolerance ){
+                break_point := true
+                break
+            }
+        }
+        if (break_point)
+            break
+        gosub, PressX
+        sleep %color_2_delay%
+        sleep, %bm_delay%
+    }
+    ;ToolTip, Found color 2, 100, 100, Screen
+    Sleep, 200
+    controller.Buttons.Circle.SetState(true) 
+    Sleep, 200
+    controller.Buttons.Circle.SetState(false) 
+    Sleep, 200
+    controller.Dpad.SetState("Right") 
+    Sleep, 200
+    controller.Dpad.SetState("None") 
+    Sleep, 500
+    gosub, PressX
+    Sleep, %ps_load_time1%
+	gosub, PressX
+	Sleep, 1000
+	controller.Buttons.Circle.SetState(true) 
+    Sleep, 200
+    controller.Buttons.Circle.SetState(false) 
+	loop, 2 {
+		gosub, PressX
+		Sleep, 500
+	}
+	Sleep, %ps_load_time2%
+	controller.Dpad.SetState("Down") 
+    Sleep, 200
+    controller.Dpad.SetState("None") 
+	Sleep, 500
+	loop, %menu_loops% {
+		controller.Dpad.SetState(MenuDirect) 
+		Sleep, 125
+		controller.Dpad.SetState("None") 
+		Sleep, 200
+	}
+	loop, 2{
+        gosub, PressX
+        Sleep, 1200
+    }
+	Sleep, %ps_load_time3%
+	loop, 2{
+        gosub, PressX
+        Sleep, 1000
+    }
+    return
+
+    loop, 9{
+        gosub, PressX
+        Sleep, 1700
+    }
+    Sleep, 2000
+    controller.Dpad.SetState("Right") 
+    Sleep, 200
+    controller.Dpad.SetState("None") 
+    Sleep, 500
+    gosub, PressX
+    Sleep, %ps_load_time1%
+	gosub, PressX
+	Sleep, 1000
+	controller.Buttons.Circle.SetState(true) 
+    Sleep, 200
+    controller.Buttons.Circle.SetState(false) 
+	loop, 2 {
+		gosub, PressX
+		Sleep, 500
+	}
+	Sleep,  %ps_load_time2%
+	controller.Dpad.SetState("Down") 
+    Sleep, 200
+    controller.Dpad.SetState("None") 
+	Sleep, 500
+	loop, %menu_loops% {
+		controller.Dpad.SetState(MenuDirect)
+		Sleep, 125
+		controller.Dpad.SetState("None") 
+		Sleep, 400
+	}
+	loop, 2{
+        gosub, PressX
+        Sleep, 2000
+    }
+	Sleep,  %ps_load_time3%
+    gosub, PressX
+    Sleep, 2000
+    
+    
+    return
+;; General Functions for AHK
+
+PixelTuning:
+x_ratio := ps_win_width/640
+y_ratio := ps_win_height/360
+pix1x := Floor(pix1x*x_ratio)
+pix1y := Floor(pix1y*y_ratio)
+pix2x := Floor(pix2x*x_ratio)
+pix2y := Floor(pix2y*y_ratio)
+tyreX := Floor(tyreX*x_ratio)
+tyreY := Floor(tyreY*y_ratio)
+purchaseX := Floor(purchaseX*x_ratio)
+purchaseY := Floor(purchaseY*y_ratio)
+acquiredX := Floor(acquiredX*x_ratio)
+acquiredY := Floor(purchaseY*y_ratio)
+return
+
+GrabRemotePlay:
+WinGet, remotePlay_id, List, ahk_exe RemotePlay.exe
+if (remotePlay_id = 0)
+{
+    MsgBox, PS4 Remote Play not found
+    return
+}
+Loop, %remotePlay_id%
+{
+  id := remotePlay_id%A_Index%
+  WinGetTitle, title, % "ahk_id " id
+  If InStr(title, "PS Remote Play")
+    break
+}    
+WinGetClass, remotePlay_class, ahk_id %id%
+WinMove, ahk_id %id%,,  0, 0, 640, 360
+ControlFocus,, ahk_class %remotePlay_class%
+WinActivate, ahk_id %id%
+GetClientSize(id, ps_win_width, ps_win_height)
+gosub, PixelTuning
+return
+
+RPwind:
+WinGet, remotePlay_id, List, ahk_exe RemotePlay.exe
+if (remotePlay_id = 0)
+{
+    MsgBox, PS4 Remote Play not found
+    return
+}
+Loop, %remotePlay_id%
+{
+  id := remotePlay_id%A_Index%
+  WinGetTitle, title, % "ahk_id " id
+  If InStr(title, "PS Remote Play")
+    break
+}    
+WinGetClass, remotePlay_class, ahk_id %id%
+WinMove, ahk_id %id%,,  -700, -400, 640, 360
+ControlFocus,, ahk_class %remotePlay_class%
+WinActivate, ahk_id %id%
+return
+
+PixelColorSimple(pc_x, pc_y)
+{
+    WinGet, remotePlay_id, List, ahk_exe RemotePlay.exe
+    if (remotePlay_id = 0)
+    {
+        MsgBox, PS4 Remote Play not found
+        return
+    }
+    if remotePlay_id
+    {
+        pc_wID := remotePlay_id[0]
+        pc_hDC := DllCall("GetDC", "UInt", pc_wID)
+        pc_fmtI := A_FormatInteger
+        SetFormat, IntegerFast, Hex
+        pc_c := DllCall("GetPixel", "UInt", pc_hDC, "Int", pc_x, "Int", pc_y, "UInt")
+        pc_c := pc_c >> 16 & 0xff | pc_c & 0xff00 | (pc_c & 0xff) << 16
+        pc_c .= ""
+        SetFormat, IntegerFast, %pc_fmtI%
+        DllCall("ReleaseDC", "UInt", pc_wID, "UInt", pc_hDC)
+        return pc_c
+        
+    }
+}
+
+GetClientSize(hWnd, ByRef w := "", ByRef h := "")
+{
+    VarSetCapacity(rect, 16)
+    DllCall("GetClientRect", "ptr", hWnd, "ptr", &rect)
+    w := NumGet(rect, 8, "int")
+    h := NumGet(rect, 12, "int")
+}
+
+Distance(c1, c2)
+{ ; function by [VxE], return value range = [0, 441.67295593006372]
+return Sqrt((((c1>>16)-(c2>>16))**2)+(((c1>>8&255)-(c2>>8&255))**2)+(((c1&255)-(c1&255))**2))
+}
+
+ConvertARGB(ARGB, Convert := 0)
+{
+    SetFormat, IntegerFast, Hex
+    RGB += ARGB
+    RGB := RGB & 0x00FFFFFF
+    if (Convert)
+        RGB := (RGB & 0xFF000000) | ((RGB & 0xFF0000) >> 16) | (RGB & 0x00FF00) | ((RGB & 0x0000FF) << 16)
+    
+    return RGB
+}
+
+MenuTest:
+MsgBox, This will test the number of Left/Right presses at the championship selection menu. `nTry this if you have not finished all cafe menus. `nPress OK to test
+gosub, GrabRemotePlay
+Gui, Submit, NoHide
+loop, %menu_loops% {
+		controller.Dpad.SetState(MenuDirect) 
+		Sleep, 125
+		controller.Dpad.SetState("None") 
+		Sleep, 200
+	}
+return
+
+BitGrab(x, y, b)
+{
+    HWND := WinExist("PS Remote Play")
+    pToken := Gdip_Startup()
+    pBitmap := Gdip_BitmapFromHWND2(hwnd)
+    
+    pixs := []
+    for i in range(-1*b, b+1){
+        for j in range(-1*b, b+1){
+            pixel := Gdip_GetPixel(pBitmap,x+i,y+j)
+            rgb := ConvertARGB( pixel )
+            pixs.Push(rgb)
+        }
+    }
+
+    Gdip_DisposeImage(pBitmap)
+    Gdip_Shutdown(pToken)
+    return pixs
+}
+
+Gdip_BitmapFromHWND2(hwnd)
+{
+    WinGetPos,,, Width, Height, ahk_id %hwnd%
+    hbm := CreateDIBSection(Width, Height), hdc := CreateCompatibleDC(), obm := SelectObject(hdc, hbm)
+    RegExMatch(A_OsVersion, "\d+", Version)
+    PrintWindow(hwnd, hdc, Version >= 8 ? 2 : 0)
+    pBitmap := Gdip_CreateBitmapFromHBITMAP(hbm)
+    SelectObject(hdc, obm), DeleteObject(hbm), DeleteDC(hdc)
+    return pBitmap
+}
+
+GetColo_p:
+gosub, GrabRemotePlay
+color_check1 := PixelColorSimple(pix1x, pix1y)
+return
+
+GetColo_g:
+gosub, GrabRemotePlay
+color_check2 := PixelColorSimple(pix2x, pix2y)
+return
+
+PSystem:
+Gui, Submit, NoHide
+if (SysCheck = 1){
+    ps_load_time1 := 14000
+    ps_load_time2 := 7000 
+    ps_load_time3 := 8400
+}
+if (SysCheck = 2){
+    ps_load_time1 := 41500
+    ps_load_time2 := 12000
+    ps_load_time3 := 40000
+}
+if (SysCheck = 3){
+    ps_load_time1 := 37000
+    ps_load_time2 := 12000
+    ps_load_time3 := 32000
+}
+return
+
+MenuSel:
+Gui, Submit, NoHide
+if (MenuCheck = 1){
+    menu_s := 1
+}
+if (MenuCheck = 2){
+    menu_s := 2
+}
+return
+
+Reset:
+gosub, PauseLoop
+Reload
+Sleep 1000
+return
+
+PauseLoop:
+    controller.Buttons.Cross.SetState(false) 
+	controller.Dpad.SetState("None") 
+    controller.Buttons.RS.SetState(false)
+    controller.Axes.LX.SetState(50)
+    return
+    
+range(start, stop:="", step:=1) {
+	static range := { _NewEnum: Func("_RangeNewEnum") }
+	if !step
+		throw "range(): Parameter 'step' must not be 0 or blank"
+	if (stop == "")
+		stop := start, start := 0
+	; Formula: r[i] := start + step*i ; r = range object, i = 0-based index
+	; For a postive 'step', the constraints are i >= 0 and r[i] < stop
+	; For a negative 'step', the constraints are i >= 0 and r[i] > stop
+	; No result is returned if r[0] does not meet the value constraint
+	if (step > 0 ? start < stop : start > stop) ;// start == start + step*0
+		return { base: range, start: start, stop: stop, step: step }
+}
+
+_RangeNewEnum(r) {
+	static enum := { "Next": Func("_RangeEnumNext") }
+	return { base: enum, r: r, i: 0 }
+}
+
+_RangeEnumNext(enum, ByRef k, ByRef v:="") {
+	stop := enum.r.stop, step := enum.r.step
+	, k := enum.r.start + step*enum.i
+	if (ret := step > 0 ? k < stop : k > stop)
+		enum.i += 1
+	return ret
+}
+
+GuiClose:
+    gosub, PauseLoop
+    ExitApp
+
+^Esc::ExitApp