initial commit

bnowakow/Lib/AHK-ViGEm-Bus.ahk

@@ -0,0 +1,211 @@
+#include %A_LineFile%\..\CLR.ahk
+
+; Static class, holds ViGEm Client instance
+class ViGEmWrapper {
+	static asm := 0
+	static client := 0
+	
+	Init(){
+		if (this.client == 0){
+			this.asm := CLR_LoadLibrary(A_LineFile "\..\ViGEmWrapper.dll")
+		}
+	}
+	
+	CreateInstance(cls){
+		return this.asm.CreateInstance(cls)
+	}
+
+}
+
+; Base class for ViGEm "Targets" (Controller types - eg xb360 / ds4) to inherit from
+class ViGEmTarget {
+	target := 0
+	helperClass := ""
+	controllerClass := ""
+
+	__New(){
+		;~ this.asm := CLR_LoadLibrary(A_LineFile "\..\ViGEmWrapper.dll")
+		ViGEmWrapper.Init()
+		this.Instance := ViGEmWrapper.CreateInstance(this.helperClass)
+		
+		if (this.Instance.OkCheck() != "OK"){
+			msgbox ViGEmWrapper.dll failed to load!
+			ExitApp
+		}
+	}
+	
+	SendReport(){
+		this.Instance.SendReport()
+	}
+	
+	SubscribeFeedback(callback){
+		this.Instance.SubscribeFeedback(callback)
+	}
+}
+
+; DS4 (DualShock 4 for Playstation 4)
+class ViGEmDS4 extends ViGEmTarget {
+	helperClass := "ViGEmWrapper.Ds4"
+	__New(){
+		static buttons := {Square: 16, Cross: 32, Circle: 64, Triangle: 128, L1: 256, R1: 512, L2: 1024, R2: 2048
+			, Share: 4096, Options: 8192, LS: 16384, RS: 32768 }
+		static specialButtons := {Ps: 1, TouchPad: 2}
+		static axes := {LX: 2, LY: 3, RX: 4, RY: 5, LT: 0, RT: 1}
+		
+		this.Buttons := {}
+		for name, id in buttons {
+			this.Buttons[name] := new this._ButtonHelper(this, id)
+		}
+		for name, id in specialButtons {
+			this.Buttons[name] := new this._SpecialButtonHelper(this, id)
+		}
+		
+		this.Axes := {}
+		for name, id in axes {
+			this.Axes[name] := new this._AxisHelper(this, id)
+		}
+		
+		this.Dpad := new this._DpadHelper(this)
+		base.__New()
+	}
+	
+	class _ButtonHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetButtonState(this._Id, state)
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+	}
+	
+	class _SpecialButtonHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetSpecialButtonState(this._Id, state)
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+	}
+	
+	class _AxisHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetAxisState(this._Id, this.ConvertAxis(state))
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+		
+		ConvertAxis(state){
+			return round(state * 2.55)
+		}
+	}
+	
+	class _DpadHelper {
+		__New(parent){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			static dPadDirections := {Up: 0, UpRight: 1, Right: 2, DownRight: 3, Down: 4, DownLeft: 5, Left: 6, UpLeft: 7, None: 8}
+			this._Parent.Instance.SetDpadState(dPadDirections[state])
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+	}
+}
+
+; Xb360
+class ViGEmXb360 extends ViGEmTarget {
+	helperClass := "ViGEmWrapper.Xb360"
+	__New(){
+		static buttons := {A: 4096, B: 8192, X: 16384, Y: 32768, LB: 256, RB: 512, LS: 64, RS: 128, Back: 32, Start: 16, Xbox: 1024}
+		static axes := {LX: 2, LY: 3, RX: 4, RY: 5, LT: 0, RT: 1}
+		
+		this.Buttons := {}
+		for name, id in buttons {
+			this.Buttons[name] := new this._ButtonHelper(this, id)
+		}
+		
+		this.Axes := {}
+		for name, id in axes {
+			this.Axes[name] := new this._AxisHelper(this, id)
+		}
+		
+		this.Dpad := new this._DpadHelper(this)
+		
+		base.__New()
+	}
+	
+	class _ButtonHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetButtonState(this._Id, state)
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+	}
+	
+	class _AxisHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetAxisState(this._Id, this.ConvertAxis(state))
+			this._Parent.Instance.SendReport()
+		}
+		
+		ConvertAxis(state){
+			value := round((state * 655.36) - 32768)
+			if (value == 32768)
+				return 32767
+			return value
+		}
+	}
+	
+	class _DpadHelper {
+		_DpadStates := {1:0, 8:0, 2:0, 4:0} ; Up, Right, Down, Left
+		__New(parent){
+			this._Parent := parent
+		}
+		
+		SetState(state){
+			static dpadDirections := { None: {1:0, 8:0, 2:0, 4:0}
+				, Up: {1:1, 8:0, 2:0, 4:0}
+				, UpRight: {1:1, 8:1, 2:0, 4:0}
+				, Right: {1:0, 8:1, 2:0, 4:0}
+				, DownRight: {1:0, 8:1, 2:1, 4:0}
+				, Down: {1:0, 8:0, 2:1, 4:0}
+				, DownLeft: {1:0, 8:0, 2:1, 4:1}
+				, Left: {1:0, 8:0, 2:0, 4:1}
+				, UpLeft: {1:1, 8:0, 2:0, 4:1}}
+			newStates := dpadDirections[state]
+			for id, newState in newStates {
+				oldState := this._DpadStates[id]
+				if (oldState != newState){
+					this._DpadStates[id] := newState
+					this._Parent.Instance.SetButtonState(id, newState)
+				}
+				this._Parent.SendReport()
+			}
+		}
+	}
+}

bnowakow/Lib/CLR.ahk

@@ -0,0 +1,151 @@
+; ==========================================================
+;                  .NET Framework Interop
+;      https://autohotkey.com/boards/viewtopic.php?t=4633
+; ==========================================================
+;
+;   Author:     Lexikos
+;   Version:    1.2
+;   Requires:	AutoHotkey_L v1.0.96+
+;
+
+CLR_LoadLibrary(AssemblyName, AppDomain=0)
+{
+	if !AppDomain
+		AppDomain := CLR_GetDefaultDomain()
+	e := ComObjError(0)
+	Loop 1 {
+		if assembly := AppDomain.Load_2(AssemblyName)
+			break
+		static null := ComObject(13,0)
+		args := ComObjArray(0xC, 1),  args[0] := AssemblyName
+		typeofAssembly := AppDomain.GetType().Assembly.GetType()
+		if assembly := typeofAssembly.InvokeMember_3("LoadWithPartialName", 0x158, null, null, args)
+			break
+		if assembly := typeofAssembly.InvokeMember_3("LoadFrom", 0x158, null, null, args)
+			break
+	}
+	ComObjError(e)
+	return assembly
+}
+
+CLR_CreateObject(Assembly, TypeName, Args*)
+{
+	if !(argCount := Args.MaxIndex())
+		return Assembly.CreateInstance_2(TypeName, true)
+	
+	vargs := ComObjArray(0xC, argCount)
+	Loop % argCount
+		vargs[A_Index-1] := Args[A_Index]
+	
+	static Array_Empty := ComObjArray(0xC,0), null := ComObject(13,0)
+	
+	return Assembly.CreateInstance_3(TypeName, true, 0, null, vargs, null, Array_Empty)
+}
+
+CLR_CompileC#(Code, References="", AppDomain=0, FileName="", CompilerOptions="")
+{
+	return CLR_CompileAssembly(Code, References, "System", "Microsoft.CSharp.CSharpCodeProvider", AppDomain, FileName, CompilerOptions)
+}
+
+CLR_CompileVB(Code, References="", AppDomain=0, FileName="", CompilerOptions="")
+{
+	return CLR_CompileAssembly(Code, References, "System", "Microsoft.VisualBasic.VBCodeProvider", AppDomain, FileName, CompilerOptions)
+}
+
+CLR_StartDomain(ByRef AppDomain, BaseDirectory="")
+{
+	static null := ComObject(13,0)
+	args := ComObjArray(0xC, 5), args[0] := "", args[2] := BaseDirectory, args[4] := ComObject(0xB,false)
+	AppDomain := CLR_GetDefaultDomain().GetType().InvokeMember_3("CreateDomain", 0x158, null, null, args)
+	return A_LastError >= 0
+}
+
+CLR_StopDomain(ByRef AppDomain)
+{	; ICorRuntimeHost::UnloadDomain
+	DllCall("SetLastError", "uint", hr := DllCall(NumGet(NumGet(0+RtHst:=CLR_Start())+20*A_PtrSize), "ptr", RtHst, "ptr", ComObjValue(AppDomain))), AppDomain := ""
+	return hr >= 0
+}
+
+; NOTE: IT IS NOT NECESSARY TO CALL THIS FUNCTION unless you need to load a specific version.
+CLR_Start(Version="") ; returns ICorRuntimeHost*
+{
+	static RtHst := 0
+	; The simple method gives no control over versioning, and seems to load .NET v2 even when v4 is present:
+	; return RtHst ? RtHst : (RtHst:=COM_CreateObject("CLRMetaData.CorRuntimeHost","{CB2F6722-AB3A-11D2-9C40-00C04FA30A3E}"), DllCall(NumGet(NumGet(RtHst+0)+40),"uint",RtHst))
+	if RtHst
+		return RtHst
+	EnvGet SystemRoot, SystemRoot
+	if Version =
+		Loop % SystemRoot "\Microsoft.NET\Framework" (A_PtrSize=8?"64":"") "\*", 2
+			if (FileExist(A_LoopFileFullPath "\mscorlib.dll") && A_LoopFileName > Version)
+				Version := A_LoopFileName
+	if DllCall("mscoree\CorBindToRuntimeEx", "wstr", Version, "ptr", 0, "uint", 0
+	, "ptr", CLR_GUID(CLSID_CorRuntimeHost, "{CB2F6723-AB3A-11D2-9C40-00C04FA30A3E}")
+	, "ptr", CLR_GUID(IID_ICorRuntimeHost,  "{CB2F6722-AB3A-11D2-9C40-00C04FA30A3E}")
+	, "ptr*", RtHst) >= 0
+		DllCall(NumGet(NumGet(RtHst+0)+10*A_PtrSize), "ptr", RtHst) ; Start
+	return RtHst
+}
+
+;
+; INTERNAL FUNCTIONS
+;
+
+CLR_GetDefaultDomain()
+{
+	static defaultDomain := 0
+	if !defaultDomain
+	{	; ICorRuntimeHost::GetDefaultDomain
+		if DllCall(NumGet(NumGet(0+RtHst:=CLR_Start())+13*A_PtrSize), "ptr", RtHst, "ptr*", p:=0) >= 0
+			defaultDomain := ComObject(p), ObjRelease(p)
+	}
+	return defaultDomain
+}
+
+CLR_CompileAssembly(Code, References, ProviderAssembly, ProviderType, AppDomain=0, FileName="", CompilerOptions="")
+{
+	if !AppDomain
+		AppDomain := CLR_GetDefaultDomain()
+	
+	if !(asmProvider := CLR_LoadLibrary(ProviderAssembly, AppDomain))
+	|| !(codeProvider := asmProvider.CreateInstance(ProviderType))
+	|| !(codeCompiler := codeProvider.CreateCompiler())
+		return 0
+
+	if !(asmSystem := (ProviderAssembly="System") ? asmProvider : CLR_LoadLibrary("System", AppDomain))
+		return 0
+	
+	; Convert | delimited list of references into an array.
+	StringSplit, Refs, References, |, %A_Space%%A_Tab%
+	aRefs := ComObjArray(8, Refs0)
+	Loop % Refs0
+		aRefs[A_Index-1] := Refs%A_Index%
+	
+	; Set parameters for compiler.
+	prms := CLR_CreateObject(asmSystem, "System.CodeDom.Compiler.CompilerParameters", aRefs)
+	, prms.OutputAssembly          := FileName
+	, prms.GenerateInMemory        := FileName=""
+	, prms.GenerateExecutable      := SubStr(FileName,-3)=".exe"
+	, prms.CompilerOptions         := CompilerOptions
+	, prms.IncludeDebugInformation := true
+	
+	; Compile!
+	compilerRes := codeCompiler.CompileAssemblyFromSource(prms, Code)
+	
+	if error_count := (errors := compilerRes.Errors).Count
+	{
+		error_text := ""
+		Loop % error_count
+			error_text .= ((e := errors.Item[A_Index-1]).IsWarning ? "Warning " : "Error ") . e.ErrorNumber " on line " e.Line ": " e.ErrorText "`n`n"
+		MsgBox, 16, Compilation Failed, %error_text%
+		return 0
+	}
+	; Success. Return Assembly object or path.
+	return compilerRes[FileName="" ? "CompiledAssembly" : "PathToAssembly"]
+}
+
+CLR_GUID(ByRef GUID, sGUID)
+{
+	VarSetCapacity(GUID, 16, 0)
+	return DllCall("ole32\CLSIDFromString", "wstr", sGUID, "ptr", &GUID) >= 0 ? &GUID : ""
+}