add versions of clubman and tokyo

bnowakow/old versions/5 Tokyo/GT7-TOKYO-9.2/Lib/AHK-ViGEm-Bus.ahk

@@ -0,0 +1,211 @@
+#include %A_LineFile%\..\CLR.ahk
+
+; Static class, holds ViGEm Client instance
+class ViGEmWrapper {
+	static asm := 0
+	static client := 0
+	
+	Init(){
+		if (this.client == 0){
+			this.asm := CLR_LoadLibrary(A_LineFile "\..\ViGEmWrapper.dll")
+		}
+	}
+	
+	CreateInstance(cls){
+		return this.asm.CreateInstance(cls)
+	}
+
+}
+
+; Base class for ViGEm "Targets" (Controller types - eg xb360 / ds4) to inherit from
+class ViGEmTarget {
+	target := 0
+	helperClass := ""
+	controllerClass := ""
+
+	__New(){
+		;~ this.asm := CLR_LoadLibrary(A_LineFile "\..\ViGEmWrapper.dll")
+		ViGEmWrapper.Init()
+		this.Instance := ViGEmWrapper.CreateInstance(this.helperClass)
+		
+		if (this.Instance.OkCheck() != "OK"){
+			msgbox ViGEmWrapper.dll failed to load!
+			ExitApp
+		}
+	}
+	
+	SendReport(){
+		this.Instance.SendReport()
+	}
+	
+	SubscribeFeedback(callback){
+		this.Instance.SubscribeFeedback(callback)
+	}
+}
+
+; DS4 (DualShock 4 for Playstation 4)
+class ViGEmDS4 extends ViGEmTarget {
+	helperClass := "ViGEmWrapper.Ds4"
+	__New(){
+		static buttons := {Square: 16, Cross: 32, Circle: 64, Triangle: 128, L1: 256, R1: 512, L2: 1024, R2: 2048
+			, Share: 4096, Options: 8192, LS: 16384, RS: 32768 }
+		static specialButtons := {Ps: 1, TouchPad: 2}
+		static axes := {LX: 2, LY: 3, RX: 4, RY: 5, LT: 0, RT: 1}
+		
+		this.Buttons := {}
+		for name, id in buttons {
+			this.Buttons[name] := new this._ButtonHelper(this, id)
+		}
+		for name, id in specialButtons {
+			this.Buttons[name] := new this._SpecialButtonHelper(this, id)
+		}
+		
+		this.Axes := {}
+		for name, id in axes {
+			this.Axes[name] := new this._AxisHelper(this, id)
+		}
+		
+		this.Dpad := new this._DpadHelper(this)
+		base.__New()
+	}
+	
+	class _ButtonHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetButtonState(this._Id, state)
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+	}
+	
+	class _SpecialButtonHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetSpecialButtonState(this._Id, state)
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+	}
+	
+	class _AxisHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetAxisState(this._Id, this.ConvertAxis(state))
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+		
+		ConvertAxis(state){
+			return round(state * 2.55)
+		}
+	}
+	
+	class _DpadHelper {
+		__New(parent){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			static dPadDirections := {Up: 0, UpRight: 1, Right: 2, DownRight: 3, Down: 4, DownLeft: 5, Left: 6, UpLeft: 7, None: 8}
+			this._Parent.Instance.SetDpadState(dPadDirections[state])
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+	}
+}
+
+; Xb360
+class ViGEmXb360 extends ViGEmTarget {
+	helperClass := "ViGEmWrapper.Xb360"
+	__New(){
+		static buttons := {A: 4096, B: 8192, X: 16384, Y: 32768, LB: 256, RB: 512, LS: 64, RS: 128, Back: 32, Start: 16, Xbox: 1024}
+		static axes := {LX: 2, LY: 3, RX: 4, RY: 5, LT: 0, RT: 1}
+		
+		this.Buttons := {}
+		for name, id in buttons {
+			this.Buttons[name] := new this._ButtonHelper(this, id)
+		}
+		
+		this.Axes := {}
+		for name, id in axes {
+			this.Axes[name] := new this._AxisHelper(this, id)
+		}
+		
+		this.Dpad := new this._DpadHelper(this)
+		
+		base.__New()
+	}
+	
+	class _ButtonHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._Id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetButtonState(this._Id, state)
+			this._Parent.Instance.SendReport()
+			return this._Parent
+		}
+	}
+	
+	class _AxisHelper {
+		__New(parent, id){
+			this._Parent := parent
+			this._id := id
+		}
+		
+		SetState(state){
+			this._Parent.Instance.SetAxisState(this._Id, this.ConvertAxis(state))
+			this._Parent.Instance.SendReport()
+		}
+		
+		ConvertAxis(state){
+			value := round((state * 655.36) - 32768)
+			if (value == 32768)
+				return 32767
+			return value
+		}
+	}
+	
+	class _DpadHelper {
+		_DpadStates := {1:0, 8:0, 2:0, 4:0} ; Up, Right, Down, Left
+		__New(parent){
+			this._Parent := parent
+		}
+		
+		SetState(state){
+			static dpadDirections := { None: {1:0, 8:0, 2:0, 4:0}
+				, Up: {1:1, 8:0, 2:0, 4:0}
+				, UpRight: {1:1, 8:1, 2:0, 4:0}
+				, Right: {1:0, 8:1, 2:0, 4:0}
+				, DownRight: {1:0, 8:1, 2:1, 4:0}
+				, Down: {1:0, 8:0, 2:1, 4:0}
+				, DownLeft: {1:0, 8:0, 2:1, 4:1}
+				, Left: {1:0, 8:0, 2:0, 4:1}
+				, UpLeft: {1:1, 8:0, 2:0, 4:1}}
+			newStates := dpadDirections[state]
+			for id, newState in newStates {
+				oldState := this._DpadStates[id]
+				if (oldState != newState){
+					this._DpadStates[id] := newState
+					this._Parent.Instance.SetButtonState(id, newState)
+				}
+				this._Parent.SendReport()
+			}
+		}
+	}
+}

bnowakow/old versions/5 Tokyo/GT7-TOKYO-9.2/Lib/CLR.ahk

@@ -0,0 +1,151 @@
+; ==========================================================
+;                  .NET Framework Interop
+;      https://autohotkey.com/boards/viewtopic.php?t=4633
+; ==========================================================
+;
+;   Author:     Lexikos
+;   Version:    1.2
+;   Requires:	AutoHotkey_L v1.0.96+
+;
+
+CLR_LoadLibrary(AssemblyName, AppDomain=0)
+{
+	if !AppDomain
+		AppDomain := CLR_GetDefaultDomain()
+	e := ComObjError(0)
+	Loop 1 {
+		if assembly := AppDomain.Load_2(AssemblyName)
+			break
+		static null := ComObject(13,0)
+		args := ComObjArray(0xC, 1),  args[0] := AssemblyName
+		typeofAssembly := AppDomain.GetType().Assembly.GetType()
+		if assembly := typeofAssembly.InvokeMember_3("LoadWithPartialName", 0x158, null, null, args)
+			break
+		if assembly := typeofAssembly.InvokeMember_3("LoadFrom", 0x158, null, null, args)
+			break
+	}
+	ComObjError(e)
+	return assembly
+}
+
+CLR_CreateObject(Assembly, TypeName, Args*)
+{
+	if !(argCount := Args.MaxIndex())
+		return Assembly.CreateInstance_2(TypeName, true)
+	
+	vargs := ComObjArray(0xC, argCount)
+	Loop % argCount
+		vargs[A_Index-1] := Args[A_Index]
+	
+	static Array_Empty := ComObjArray(0xC,0), null := ComObject(13,0)
+	
+	return Assembly.CreateInstance_3(TypeName, true, 0, null, vargs, null, Array_Empty)
+}
+
+CLR_CompileC#(Code, References="", AppDomain=0, FileName="", CompilerOptions="")
+{
+	return CLR_CompileAssembly(Code, References, "System", "Microsoft.CSharp.CSharpCodeProvider", AppDomain, FileName, CompilerOptions)
+}
+
+CLR_CompileVB(Code, References="", AppDomain=0, FileName="", CompilerOptions="")
+{
+	return CLR_CompileAssembly(Code, References, "System", "Microsoft.VisualBasic.VBCodeProvider", AppDomain, FileName, CompilerOptions)
+}
+
+CLR_StartDomain(ByRef AppDomain, BaseDirectory="")
+{
+	static null := ComObject(13,0)
+	args := ComObjArray(0xC, 5), args[0] := "", args[2] := BaseDirectory, args[4] := ComObject(0xB,false)
+	AppDomain := CLR_GetDefaultDomain().GetType().InvokeMember_3("CreateDomain", 0x158, null, null, args)
+	return A_LastError >= 0
+}
+
+CLR_StopDomain(ByRef AppDomain)
+{	; ICorRuntimeHost::UnloadDomain
+	DllCall("SetLastError", "uint", hr := DllCall(NumGet(NumGet(0+RtHst:=CLR_Start())+20*A_PtrSize), "ptr", RtHst, "ptr", ComObjValue(AppDomain))), AppDomain := ""
+	return hr >= 0
+}
+
+; NOTE: IT IS NOT NECESSARY TO CALL THIS FUNCTION unless you need to load a specific version.
+CLR_Start(Version="") ; returns ICorRuntimeHost*
+{
+	static RtHst := 0
+	; The simple method gives no control over versioning, and seems to load .NET v2 even when v4 is present:
+	; return RtHst ? RtHst : (RtHst:=COM_CreateObject("CLRMetaData.CorRuntimeHost","{CB2F6722-AB3A-11D2-9C40-00C04FA30A3E}"), DllCall(NumGet(NumGet(RtHst+0)+40),"uint",RtHst))
+	if RtHst
+		return RtHst
+	EnvGet SystemRoot, SystemRoot
+	if Version =
+		Loop % SystemRoot "\Microsoft.NET\Framework" (A_PtrSize=8?"64":"") "\*", 2
+			if (FileExist(A_LoopFileFullPath "\mscorlib.dll") && A_LoopFileName > Version)
+				Version := A_LoopFileName
+	if DllCall("mscoree\CorBindToRuntimeEx", "wstr", Version, "ptr", 0, "uint", 0
+	, "ptr", CLR_GUID(CLSID_CorRuntimeHost, "{CB2F6723-AB3A-11D2-9C40-00C04FA30A3E}")
+	, "ptr", CLR_GUID(IID_ICorRuntimeHost,  "{CB2F6722-AB3A-11D2-9C40-00C04FA30A3E}")
+	, "ptr*", RtHst) >= 0
+		DllCall(NumGet(NumGet(RtHst+0)+10*A_PtrSize), "ptr", RtHst) ; Start
+	return RtHst
+}
+
+;
+; INTERNAL FUNCTIONS
+;
+
+CLR_GetDefaultDomain()
+{
+	static defaultDomain := 0
+	if !defaultDomain
+	{	; ICorRuntimeHost::GetDefaultDomain
+		if DllCall(NumGet(NumGet(0+RtHst:=CLR_Start())+13*A_PtrSize), "ptr", RtHst, "ptr*", p:=0) >= 0
+			defaultDomain := ComObject(p), ObjRelease(p)
+	}
+	return defaultDomain
+}
+
+CLR_CompileAssembly(Code, References, ProviderAssembly, ProviderType, AppDomain=0, FileName="", CompilerOptions="")
+{
+	if !AppDomain
+		AppDomain := CLR_GetDefaultDomain()
+	
+	if !(asmProvider := CLR_LoadLibrary(ProviderAssembly, AppDomain))
+	|| !(codeProvider := asmProvider.CreateInstance(ProviderType))
+	|| !(codeCompiler := codeProvider.CreateCompiler())
+		return 0
+
+	if !(asmSystem := (ProviderAssembly="System") ? asmProvider : CLR_LoadLibrary("System", AppDomain))
+		return 0
+	
+	; Convert | delimited list of references into an array.
+	StringSplit, Refs, References, |, %A_Space%%A_Tab%
+	aRefs := ComObjArray(8, Refs0)
+	Loop % Refs0
+		aRefs[A_Index-1] := Refs%A_Index%
+	
+	; Set parameters for compiler.
+	prms := CLR_CreateObject(asmSystem, "System.CodeDom.Compiler.CompilerParameters", aRefs)
+	, prms.OutputAssembly          := FileName
+	, prms.GenerateInMemory        := FileName=""
+	, prms.GenerateExecutable      := SubStr(FileName,-3)=".exe"
+	, prms.CompilerOptions         := CompilerOptions
+	, prms.IncludeDebugInformation := true
+	
+	; Compile!
+	compilerRes := codeCompiler.CompileAssemblyFromSource(prms, Code)
+	
+	if error_count := (errors := compilerRes.Errors).Count
+	{
+		error_text := ""
+		Loop % error_count
+			error_text .= ((e := errors.Item[A_Index-1]).IsWarning ? "Warning " : "Error ") . e.ErrorNumber " on line " e.Line ": " e.ErrorText "`n`n"
+		MsgBox, 16, Compilation Failed, %error_text%
+		return 0
+	}
+	; Success. Return Assembly object or path.
+	return compilerRes[FileName="" ? "CompiledAssembly" : "PathToAssembly"]
+}
+
+CLR_GUID(ByRef GUID, sGUID)
+{
+	VarSetCapacity(GUID, 16, 0)
+	return DllCall("ole32\CLSIDFromString", "wstr", sGUID, "ptr", &GUID) >= 0 ? &GUID : ""
+}

bnowakow/old versions/5 Tokyo/GT7-TOKYO-9.2/Lib/__controller_functions__.ahk

@@ -0,0 +1,188 @@
+
+/**********************************************
+* Controller methods for simplicity           *
+***********************************************/
+*/
+
+GoTo EndControllerFunctionsDef
+
+;;;;;;;;;;;; Turning functions
+;;;;;;;;;;;;    For holding the stick in a specific position for a period of time
+;;;;;;;;;;;;    Note no other button may be pressed or released when these functions are ran
+
+; Set the time you want to turn for in miliseconds and how hard (50, 100), 100 being the most, 50 being neutral
+Turn_Right(sleept, inten){
+    t := sleept
+    controller.Axes.LX.SetState(inten)
+    gosub, Turn
+    controller.Axes.LX.SetState(50)
+}
+
+; Set the time you want to turn for in miliseconds and how hard (0, 50), 0 being the most
+Turn_Left(sleept, inten){
+    t := sleept
+    controller.Axes.LX.SetState(inten)
+    gosub, Turn
+    controller.Axes.LX.SetState(50)
+}
+
+;;;;;;;;;;;; Simple button press functions
+;;;;;;;;;;;;    You can pass a delay amount or leave it blank
+;;;;;;;;;;;;    Longer delays hold the button longer
+
+; Press X button
+Press_X(delay:=200){
+  controller.Buttons.Cross.SetState(true)
+  DllCall("Sleep", "UInt", delay)
+  controller.Buttons.Cross.SetState(false)
+  return
+}
+
+; Press O button
+Press_O(delay:=200){
+  controller.Buttons.Circle.SetState(true)
+  DllCall("Sleep", "UInt", delay)
+  controller.Buttons.Circle.SetState(false)
+  return
+}
+
+; Press Triangle button
+Press_Triangle(delay:=200){
+  controller.Buttons.Triangle.SetState(true)
+  DllCall("Sleep", "UInt", delay)
+  controller.Buttons.Triangle.SetState(false)
+  return
+}
+
+; Press Square button
+Press_Square(delay:=200){
+  controller.Buttons.Square.SetState(true)
+  DllCall("Sleep", "UInt", delay)
+  controller.Buttons.Square.SetState(false)
+  return
+}
+
+; Press R1 button
+Press_L1(delay:=200){
+  controller.Buttons.L1.SetState(true)
+  DllCall("Sleep", "UInt", delay)
+  controller.Buttons.L1.SetState(false)
+  return
+}
+
+; Press R1 button
+Press_R1(delay:=200){
+  controller.Buttons.R1.SetState(true)
+  DllCall("Sleep", "UInt", delay)
+  controller.Buttons.R1.SetState(false)
+  return
+}
+
+; Press Right on D-pad
+Press_Right(delay:=200){
+  controller.Dpad.SetState("Right")
+  DllCall("Sleep", "UInt", delay)
+  controller.Dpad.SetState("None")
+  return
+}
+
+; Press Left on D-pad
+Press_Left(delay:=200){
+  controller.Dpad.SetState("Left")
+  DllCall("Sleep", "UInt", delay)
+  controller.Dpad.SetState("None")
+  return
+}
+
+; Press Up on D-pad
+Press_Up(delay:=200){
+  controller.Dpad.SetState("Up")
+  DllCall("Sleep", "UInt", delay)
+  controller.Dpad.SetState("None")
+  return
+}
+
+; Press Down on D-pad
+Press_Down(delay:=200){
+  controller.Dpad.SetState("Down")
+  DllCall("Sleep", "UInt", delay)
+  controller.Dpad.SetState("None")
+  return
+}
+
+;;;;;;;;;;; Other functions specific to GT7
+
+; Turn on nitrous
+Nitrous_On(){
+  controller.Buttons.RS.SetState(true)
+}
+
+; Turn off nitrous
+Nitrous_Off(){
+  controller.Buttons.RS.SetState(false)
+}
+
+Accel_On(control:=100){
+  controller.Buttons.R2.SetState(true)
+  controller.Axes.RT.SetState(control)
+}
+
+Accel_Off(){
+  controller.Buttons.R2.SetState(false)
+  controller.Axes.RT.SetState(0)
+}
+
+Brake_On(control:=100){
+  controller.Buttons.L2.SetState(true)
+  controller.Axes.LT.SetState(control)
+}
+
+Brake_Off(){
+  controller.Buttons.L2.SetState(false)
+  controller.Axes.LT.SetState(0)
+}
+; given time t in miliseconds, turn right for that long, with intensity being how much the turn button is held for
+Turn:
+	t0 := A_TickCount
+	tf := t0+t
+	loop 	{
+        Sleep(100)
+	} until  A_TickCount > tf
+  return
+  
+
+Press_Options(){
+  controller.Buttons.Options.SetState(true)
+  Sleep, 50
+  controller.Buttons.Options.SetState(false)
+  }
+
+
+PressX:
+; Just for menuing, does not hold X down
+  controller.Buttons.Cross.SetState(true)
+  DllCall("Sleep", "UInt", 200)
+  controller.Buttons.Cross.SetState(false)
+  return
+
+PressO:
+; Just for menuing, does not hold O down
+  controller.Buttons.Circle.SetState(true)
+  DllCall("Sleep", "UInt", 200)
+  controller.Buttons.Circle.SetState(false)
+  return
+
+PressRight:
+; For turning
+  controller.Dpad.SetState("Right")
+  Sleep, 50
+  controller.Dpad.SetState("None")
+  return
+
+PressShare:
+  controller.Buttons.Share.SetState(true)
+  Sleep, 50
+  controller.Buttons.Share.SetState(false)
+  return
+
+EndControllerFunctionsDef:

bnowakow/old versions/5 Tokyo/GT7-TOKYO-9.2/Lib/__utility__.ahk

@@ -0,0 +1,136 @@
+/**********************************************
+* Only place functions here, no sub routines  *
+***********************************************/
+
+
+; Grabs the colors of the pixels (x-b, y-b) to (x+b, y+b)
+; returns the array of colors
+*/
+
+BitGrab(x, y, b)
+{
+    HWND := WinExist("PS Remote Play")
+    pToken := Gdip_Startup()
+    pBitmap := Gdip_BitmapFromHWND2(hwnd)
+
+    pixs := []
+    for i in range(-1*b, b+1){
+        for j in range(-1*b, b+1){
+            pixel := Gdip_GetPixel(pBitmap,x+i,y+j)
+            rgb := ConvertARGB( pixel )
+            pixs.Push(rgb)
+        }
+    }
+
+    Gdip_DisposeImage(pBitmap)
+    Gdip_Shutdown(pToken)
+    return pixs
+}
+
+Gdip_BitmapFromHWND2(hwnd)
+{
+    WinGetPos,,, Width, Height, ahk_id %hwnd%
+    hbm := CreateDIBSection(Width, Height), hdc := CreateCompatibleDC(), obm := SelectObject(hdc, hbm)
+    RegExMatch(A_OsVersion, "\d+", Version)
+    PrintWindow(hwnd, hdc, Version >= 8 ? 2 : 0)
+    pBitmap := Gdip_CreateBitmapFromHBITMAP(hbm)
+    SelectObject(hdc, obm), DeleteObject(hbm), DeleteDC(hdc)
+    return pBitmap
+}
+
+range(start, stop:="", step:=1) {
+	static range := { _NewEnum: Func("_RangeNewEnum") }
+	if !step
+		throw "range(): Parameter 'step' must not be 0 or blank"
+	if (stop == "")
+		stop := start, start := 0
+	; Formula: r[i] := start + step*i ; r = range object, i = 0-based index
+	; For a postive 'step', the constraints are i >= 0 and r[i] < stop
+	; For a negative 'step', the constraints are i >= 0 and r[i] > stop
+	; No result is returned if r[0] does not meet the value constraint
+	if (step > 0 ? start < stop : start > stop) ;// start == start + step*0
+		return { base: range, start: start, stop: stop, step: step }
+}
+
+_RangeNewEnum(r) {
+	static enum := { "Next": Func("_RangeEnumNext") }
+	return { base: enum, r: r, i: 0 }
+}
+
+_RangeEnumNext(enum, ByRef k, ByRef v:="") {
+	stop := enum.r.stop, step := enum.r.step
+	, k := enum.r.start + step*enum.i
+	if (ret := step > 0 ? k < stop : k > stop)
+		enum.i += 1
+	return ret
+}
+
+
+Sleep(ms=1)
+{
+		global timeBeginPeriodHasAlreadyBeenCalled
+		if (timeBeginPeriodHasAlreadyBeenCalled != 1)
+		{
+			DllCall("Winmm.dll\timeBeginPeriod", UInt, 1)
+			timeBeginPeriodHasAlreadyBeenCalled := 1
+		}
+
+	DllCall("Sleep", UInt, ms)
+}
+
+
+
+PixelColorSimple(pc_x, pc_y)
+{
+    WinGet, remotePlay_id, List, ahk_exe RemotePlay.exe
+    if (remotePlay_id = 0)
+    {
+        MsgBox, PS4 Remote Play not found
+        return
+    }
+    if remotePlay_id
+    {
+        pc_wID := remotePlay_id[0]
+        pc_hDC := DllCall("GetDC", "UInt", pc_wID)
+        pc_fmtI := A_FormatInteger
+        SetFormat, IntegerFast, Hex
+        pc_c := DllCall("GetPixel", "UInt", pc_hDC, "Int", pc_x, "Int", pc_y, "UInt")
+        pc_c := pc_c >> 16 & 0xff | pc_c & 0xff00 | (pc_c & 0xff) << 16
+        pc_c .= ""
+        SetFormat, IntegerFast, %pc_fmtI%
+        DllCall("ReleaseDC", "UInt", pc_wID, "UInt", pc_hDC)
+        return pc_c
+
+    }
+}
+
+GetClientSize(hWnd, ByRef w := "", ByRef h := "")
+{
+    VarSetCapacity(rect, 16)
+    DllCall("GetClientRect", "ptr", hWnd, "ptr", &rect)
+    w := NumGet(rect, 8, "int")
+    h := NumGet(rect, 12, "int")
+}
+
+Distance(c1, c2)
+{ ; function by [VxE], return value range = [0, 441.67295593006372]
+return Sqrt((((c1>>16)-(c2>>16))**2)+(((c1>>8&255)-(c2>>8&255))**2)+(((c1&255)-(c1&255))**2))
+}
+
+ConvertARGB(ARGB, Convert := 0)
+{
+    SetFormat, IntegerFast, Hex
+    RGB += ARGB
+    RGB := RGB & 0x00FFFFFF
+    if (Convert)
+        RGB := (RGB & 0xFF000000) | ((RGB & 0xFF0000) >> 16) | (RGB & 0x00FF00) | ((RGB & 0x0000FF) << 16)
+
+    return RGB
+}
+
+ToolTipper(msg, x := 100, y := 100)
+{
+  if (debug_mode = 1)
+    ToolTip, %msg%, x, y, Screen
+  return
+}